Как я могу прочитать содержимое каталога в Perl?

opendir(D, "/path/to/directory") || die "Can't open directory: $!\n";
while (my $f = readdir(D)) {
    print "\$f = $f\n";
}
closedir(D);

EDIT: о, извините, пропустил часть "into an array":

my $d = shift;

opendir(D, "$d") || die "Can't open directory $d: $!\n";
my @list = readdir(D);
closedir(D);

foreach my $f (@list) {
    print "\$f = $f\n";
}

EDIT2: большинство других ответов верны, но я хотел бы прокомментировать этот ответ конкретно, в котором предлагается это решение:

opendir(DIR, $somedir) || die "Can't open directory $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Во-первых, чтобы задокументировать то, что он делает, так как плакат не сделал этого: он передает возвращаемый список из readdir() через grep() , который возвращает только те значения, которые являются файлами (в отличие от каталогов, устройств, именованных каналов и т. д.) и это не начинается с точки (что делает имя списка @dots вводящим в заблуждение, но это связано с изменением, которое он сделал при копировании его из документации readdir()). Поскольку он ограничивает содержимое возвращаемого каталога, я не думаю , что это технически правильный ответ на этот вопрос, но он иллюстрирует общую идиому, используемую для фильтрации имен файлов в Perl, и я подумал, что это будет полезно для документирования. Еще один пример, который мы видели много раз::

@list = grep !/^\.\.?$/, readdir(D);

Этот фрагмент кода считывает все содержимое из дескриптора каталога D, кроме '.' и '..", так как они очень редко желательны для использования в списке.

Быстрое и грязное решение использовать глобус

@files = glob ('/path/to/dir/*');

IO::Dir хорош и обеспечивает привязанный интерфейс hash, а также.

Из perldoc:

use IO::Dir;
$d = IO::Dir->new(".");
if (defined $d) {
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

tie %dir, 'IO::Dir', ".";
foreach (keys %dir) {
    print $_, " " , $dir{$_}->size,"\n";
}

Так что вы могли бы сделать что-то вроде:

tie %dir, 'IO::Dir', $directory_name;
my @dirs = keys %dir;

Это будет сделано в одной строке (обратите внимание на подстановочный знак "*" в конце)

@files = </path/to/directory/*>;
# To demonstrate:
print join(", ", @files);

Вы могли бы использовать DirHandle :

use DirHandle;
$d = new DirHandle ".";
if (defined $d)
{
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

DirHandle предоставляет альтернативный, более чистый интерфейс для функций opendir() , closedir() , readdir() и rewinddir() .

Похоже на вышесказанное, но я думаю, что лучшая версия (слегка измененная) от " perldoc-f readdir":

opendir(DIR, $somedir) || die "can't opendir $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Вот пример рекурсии через структуру каталогов и копирования файлов из сценария резервного копирования, который я написал.

sub copy_directory {
my ($source, $dest) = @_;
my $start = time;

# get the contents of the directory.
opendir(D, $source);
my @f = readdir(D);
closedir(D);

# recurse through the directory structure and copy files.
foreach my $file (@f) {
    # Setup the full path to the source and dest files.
    my $filename = $source . "\\" . $file;
    my $destfile = $dest . "\\" . $file;

    # get the file info for the 2 files.
    my $sourceInfo = stat( $filename );
    my $destInfo = stat( $destfile );

    # make sure the destinatin directory exists.
    mkdir( $dest, 0777 );

    if ($file eq '.' || $file eq '..') {
    } elsif (-d $filename) { # if it's a directory then recurse into it.
        #print "entering $filename\n";
        copy_directory($filename, $destfile); 
    } else { 
        # Only backup the file if it has been created/modified since the last backup 
        if( (not -e $destfile) || ($sourceInfo->mtime > $destInfo->mtime ) ) {
            #print $filename . " -> " . $destfile . "\n";
            copy( $filename, $destfile ) or print "Error copying $filename: $!\n";
        } 
    } 
}

print "$source copied in " . (time - $start) . " seconds.\n";       
}

от: http://perlmeme.org/faqs/file_io/directory_listing.html

#!/usr/bin/perl
use strict;
use warnings;

my $directory = '/tmp';

opendir (DIR, $directory) or die $!;

while (my $file = readdir(DIR)) {
    next if ($file =~ m/^\./);
    print "$file\n";
}

Следующий пример (основанный на примере кода из perldoc-f readdir) возвращает все файлы (не каталоги), начинающиеся с точки из открытого каталога. Имена файлов находятся в массиве @dots.

#!/usr/bin/perl

use strict;
use warnings;

my $dir = '/tmp';

opendir(DIR, $dir) or die $!;

my @dots 
    = grep { 
        /^\./             # Begins with a period
    && -f "$dir/$_"   # and is a file
} readdir(DIR);

# Loop through the array printing out the filenames
foreach my $file (@dots) {
    print "$file\n";
}

closedir(DIR);
exit 0;


closedir(DIR);
exit 0;